summaryrefslogtreecommitdiff
path: root/git-gui/lib/status_bar.tcl
blob: d32b14142ff8383bcdfddecd1d435fbea3260a51 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
# git-gui status bar mega-widget
# Copyright (C) 2007 Shawn Pearce

# The status_bar class manages the entire status bar. It is possible for
# multiple overlapping asynchronous operations to want to display status
# simultaneously. Each one receives a status_bar_operation when it calls the
# start method, and the status bar combines all active operations into the
# line of text it displays. Most of the time, there will be at most one
# ongoing operation.
#
# Note that the entire status bar can be either in single-line or two-line
# mode, depending on the constructor. Multiple active operations are only
# supported for single-line status bars.
 
class status_bar {
 
field allow_multiple ; # configured at construction
 
field w         ; # our own window path
field w_l       ; # text widget we draw messages into
field w_c       ; # canvas we draw a progress bar into
field c_pack    ; # script to pack the canvas with
 
field baseline_text   ; # text to show if there are no operations
field status_bar_text ; # combined text for all operations
 
field operations ; # list of current ongoing operations

# The status bar can display a progress bar, updated when consumers call the
# update method on their status_bar_operation. When there are multiple
# operations, the status bar shows the combined status of all operations.
#
# When an overlapping operation completes, the progress bar is going to
# abruptly have one fewer operation in the calculation, causing a discontinuity.
# Therefore, whenever an operation completes, if it is not the last operation,
# this counter is increased, and the progress bar is calculated as though there
# were still another operation at 100%. When the last operation completes, this
# is reset to 0.
field completed_operation_count
 
constructor new {path} {
	global use_ttk NS
	set w $path
	set w_l $w.l
	set w_c $w.c

	# Standard single-line status bar: Permit overlapping operations
	set allow_multiple 1
 
	set baseline_text ""
	set operations [list]
	set completed_operation_count 0
 
	${NS}::frame $w
	if {!$use_ttk} {
		$w configure -borderwidth 1 -relief sunken
	}
	${NS}::label $w_l \
		-textvariable @status_bar_text \
		-anchor w \
		-justify left
	pack $w_l -side left
	set c_pack [cb _oneline_pack]
 
	bind $w <Destroy> [cb _delete %W]
	return $this
}
 
method _oneline_pack {} {
	$w_c conf -width 100
	pack $w_c -side right
}
 
constructor two_line {path} {
	global NS
	set w $path
	set w_l $w.l
	set w_c $w.c

	# Two-line status bar: Only one ongoing operation permitted.
	set allow_multiple 0
 
	set baseline_text ""
	set operations [list]
	set completed_operation_count 0
 
	${NS}::frame $w
	${NS}::label $w_l \
		-textvariable @status_bar_text \
		-anchor w \
		-justify left
	pack $w_l -anchor w -fill x
	set c_pack [list pack $w_c -fill x]
 
	bind $w <Destroy> [cb _delete %W]
	return $this
}
 
method ensure_canvas {} {
	if {[winfo exists $w_c]} {
		$w_c coords bar 0 0 0 20
	} else {
		canvas $w_c \
			-height [expr {int([winfo reqheight $w_l] * 0.6)}] \
			-borderwidth 1 \
			-relief groove \
			-highlightt 0
		$w_c create rectangle 0 0 0 20 -tags bar -fill navy
		eval $c_pack
	}
}
 
method show {msg} {
	$this ensure_canvas
	set baseline_text $msg
	$this refresh
}
 
method start {msg {uds {}}} {
	set baseline_text ""
 
	if {!$allow_multiple && [llength $operations]} {
		return [lindex $operations 0]
	}
 
	$this ensure_canvas
 
	set operation [status_bar_operation::new $this $msg $uds]
 
	lappend operations $operation
 
	$this refresh
 
	return $operation
}
 
method refresh {} {
	set new_text ""
 
	set total [expr $completed_operation_count * 100]
	set have $total
 
	foreach operation $operations {
		if {$new_text != ""} {
			append new_text " / "
		}
 
		append new_text [$operation get_status]
 
		set total [expr $total + 100]
		set have [expr $have + [$operation get_progress]]
	}
 
	if {$new_text == ""} {
		set new_text $baseline_text
	}
 
	set status_bar_text $new_text
 
	if {[winfo exists $w_c]} {
		set pixel_width 0
		if {$have > 0} {
			set pixel_width [expr {[winfo width $w_c] * $have / $total}]
		}
 
		$w_c coords bar 0 0 $pixel_width 20
	}
}
 
method stop {operation stop_msg} {
	set idx [lsearch $operations $operation]
 
	if {$idx >= 0} {
		set operations [lreplace $operations $idx $idx]
		set completed_operation_count [expr \
			$completed_operation_count + 1]
 
		if {[llength $operations] == 0} {
			set completed_operation_count 0
 
			destroy $w_c
			if {$stop_msg ne {}} {
				set baseline_text $stop_msg
			}
		}
 
		$this refresh
	}
}
 
method stop_all {{stop_msg {}}} {
	# This makes the operation's call to stop a no-op.
	set operations_copy $operations
	set operations [list]
 
	foreach operation $operations_copy {
		$operation stop
	}
 
	if {$stop_msg ne {}} {
		set baseline_text $stop_msg
	}
 
	$this refresh
}
 
method _delete {current} {
	if {$current eq $w} {
		delete_this
	}
}
 
}

# The status_bar_operation class tracks a single consumer's ongoing status bar
# activity, with the context that there are a few situations where multiple
# overlapping asynchronous operations might want to display status information
# simultaneously. Instances of status_bar_operation are created by calling
# start on the status_bar, and when the caller is done with its stauts bar
# operation, it calls stop on the operation.
 
class status_bar_operation {
 
field status_bar; # reference back to the status_bar that owns this object
 
field is_active;
 
field status   {}; # single line of text we show
field progress {}; # current progress (0 to 100)
field prefix   {}; # text we format into status
field units    {}; # unit of progress
field meter    {}; # current core git progress meter (if active)
 
constructor new {owner msg uds} {
	set status_bar $owner
 
	set status $msg
	set progress 0
	set prefix $msg
	set units  $uds
	set meter  {}
 
	set is_active 1
 
	return $this
}
 
method get_is_active {} { return $is_active }
method get_status {} { return $status }
method get_progress {} { return $progress }
 
method update {have total} {
	if {!$is_active} { return }
 
	set progress 0
 
	if {$total > 0} {
		set progress [expr {100 * $have / $total}]
	}
 
	set prec [string length [format %i $total]]
 
	set status [mc "%s ... %*i of %*i %s (%3i%%)" \
		$prefix \
		$prec $have \
		$prec $total \
		$units $progress]
 
	$status_bar refresh
}
 
method update_meter {buf} {
	if {!$is_active} { return }
 
	append meter $buf
	set r [string last "\r" $meter]
	if {$r == -1} {
		return
	}
 
	set prior [string range $meter 0 $r]
	set meter [string range $meter [expr {$r + 1}] end]
	set p "\\((\\d+)/(\\d+)\\)"
	if {[regexp ":\\s*\\d+% $p\(?:, done.\\s*\n|\\s*\r)\$" $prior _j a b]} {
		update $this $a $b
	} elseif {[regexp "$p\\s+done\r\$" $prior _j a b]} {
		update $this $a $b
	}
}
 
method stop {{stop_msg {}}} {
	if {$is_active} {
		set is_active 0
		$status_bar stop $this $stop_msg
	}
}
 
method restart {msg} {
	if {!$is_active} { return }
 
	set status $msg
	set prefix $msg
	set meter {}
	$status_bar refresh
}
 
method _delete {} {
	stop
	delete_this
}
 
}